Funzione ESPR.REG (espressioni regolari)

Contenuto

# ESPR.REG

Trova le corrispondenze ed estrae il testo o, eventualmente, lo sostituisce utilizzando le espressioni regolari.

### Sintassi

ESPR.REG( Testo ; Espressione [ ; [ Sostituzione ] [ ; Flag|Occorrenza ] ] )

Testo: un testo o un riferimento a una cella dove deve essere applicata l'espressione regolare.

Espressione: un testo che rappresenta l'espressione regolare tramite espressioni regolari ICU. Se non esiste corrispondenza e non viene proposta una Sostituzione, è restituito #N/D.

Sostituzione: facoltativa. Il testo sostitutivo e i riferimenti ai gruppi di cattura. Se non c'è corrispondenza, il Testo è restituito senza modifiche.

Flag: facoltativo. "g" sostituisce tutte le corrispondenze dell'Espressione nel Testo, senza estrarlo. Se non c'è corrispondenza, il Testo è restituito senza modifiche.

Occorrenza: facoltativo. Un numero che indica quale corrispondenza dell'Espressione nel Testo deve essere estratta o restituita. Se non c'è corrispondenza e non viene proposta una Sostituzione, viene restituito #N/A. Se non c'è corrispondenza e non viene proposta una Sostituzione, il Testo viene restituito senza modifiche. Se il valore dell'Occorrenza è 0, il Testo viene restituito senza modifiche.

### Esempi

=ESPR.REG("123456ABCDEF";"[:digit:]";"Z") restituisce "Z23456ABCDEF", in cui la prima occorrenza di una cifra viene sostituita da "Z".

=ESPR.REG("123456ABCDEF";"[:digit:]";"Z";"g") restituisce "ZZZZZZABCDEF", in cui tutte le occorrenze di una cifra vengono sostituite da "Z".

=ESPR.REG("123456ABCDEF";"[126]";"";"g") restituisce "345ABCDEF", in cui tutte le occorrenze di "1", "2" o "6" vengono sostituite da una stringa vuota e quindi eliminate.

=ESPR.REG("axbxcxd";".x";;2) restituisce "bx", la seconda corrispondenza di ".x".

=ESPR.REG("axbxcxd";"(.)x";"$1y";2) restituisce "axbycxd", la seconda occorrenza di "(.)x" (cioè "bx") viene sostituita dal gruppo di cattura di un solo carattere (ossia "b") seguito da "y".

#### Informazioni tecniche

La funzione è disponibile da LibreOffice 6.2.

Questa funzione NON fa parte dello standard Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Lo spazio dei nomi è

ORG.LIBREOFFICE.REGEX

Argomenti correlati

Pagina wiki relativa a ESPR.REG (in inglese).

Elenco delle espressioni regolari

Espressioni regolari ICU

Categoria Testo

Sostienici!