Funktionen SUM.HVIS (på engelsk: SUMIF)

Indhold

# SUM.HVIS (på engelsk: SUMIF)

Afgør hvilke værdier i et celleområde, der opfylder et angivet kriterium, og returnerer så summen af disse værdier. Alternativt kan funktionen afgøre, hvilke værdier i ét celleområde, der opfylder et kriterium, og så returnere summen af værdier i de tilsvarende celler i et andet celleområde.

SUM.HVIS (på engelsk: SUMIF) kan kun anvende et enkelt kriterium på et område. Brug SUM.FLERE.HVIS (på engelsk: SUMIFS), hvis du har brug for at anvende flere kriterier.

#### Syntaks

SUM.HVIS(Område; Kriterium [;SumOmråde])

Område: Området med celler, som kriteriet skal anvendes på.

SUM.HVIS understøtter kun reference-sammenkoblingsoperatoren (~) i Område-parameteren, og kun hvis den valgfrie parameter SumOmråde ikke er givet.

Kriterium1: Et kriterium er et tekstudtryk beregnet fra en enkelt cellereference, en formel, et tal eller en tekst. Det bruges i sammenligninger med celleindhold.

En henvisning til en tom celle fortolkes som den numeriske værdi 0.

Et matchende udtryk kan være:

- Et tal eller en logisk værdi. Et overensstemmende celleindhold er lig med tallet eller den logiske værdi.

- En værdi, som begynder med en sammenligning (<, <=, =, >, >=, <>).

  For = passer en tom værdi med en tom celle.

  For <> passer en tom værdi med en ikke-tom celle.

  For <> passer en ikke-tom værdi med ethvert andet celleindhold end værdien, inklusive tomme celler.

  Bemærk: "=0" matcher ikke tomme celle.

  For = and <> gælder, at hvis værdien ikke er tom og ikke kan fortolkes som en talværdi eller undertype af tal, og hvis egenskaben Søgekriterier = og <> skal gælde for hele celler er krydset af, så sker sammenligningen med hele celleindholdet. Hvis feltet ikke er afkrydset, sker sammenligning med enhver underdel af feltet, som passer med kriterierne.

- Anden tekstværdi. Hvis egenskaben Søgekriterier = og <> skal gælde for hele celler er sand, sker sammenligningen med med hele cellens indhold, hvis falsk, sker sammenligningen med enhver underdel af feltet som passer til kriterierne. Udtrykket kan indeholde tekst, tal, regulære udtryk eller jokertegn (hvis jokertegn i formler er slået til i beregningsindstillinger).

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ IndstillingerFunktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til et sprog, hvor decimaltegnet ikke er punktum, vil konverteringen fungere. For at gennemtvinge evalueringen af det regulære udtryk frem for et numerisk udtryk, bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

SumOmråde: Valgfri. Celleområdet hvorfra værdierne skal summeres. Hvis SumOmråde ikke angives, summeres værdierne i Område.

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

### Eksempler

Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Sales | Revenue
2 | pensel | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | pennalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpel brug

=SUM.HVIS(C2:C6;">=100")

Summer kun værdierne i område C2:C6 som er >=100. Returnerer 370, fordi cellerne C2:C3 ikke opfylder kriteriet. Værdierne fra Område summeres fordi SumOmråde ikke er angivet.

=SUM.HVIS(B2:B5;">=20";C2:C6)

Summerer værdier fra området B2:B2 kun hvis detilsvarende værdier i området A1:A5 er >=20. Returnerer 340, fordi den femte og den sjette række ikke opfylder kriteriet.

#### Brug af regulære udtryk

=SUM.HVIS(A2:A6;"pen";C2:C5)

Summerer kun de værdier fra området C2:C6, hvor den tilsvarende celle i området i A2:A6 præcist matcher bogstaverne "pen". Returnerer 85, fordi række A2 og A4:A6 ikke opfylder kriteriet.

=SUM.HVIS(A2:A6;"pen*";C2:C6)

Summerer kun de værdier fra området C2:C6, hvor den tilsvarende celle i området i A2:A6 indeholder bogstaverne "pen". Returnerer 150, fordi rækkerne A4:A5 ikke opfylder kriteriet.

=SUM.HVIS(Produktnavn;"pen*";Indtægter)

Et navngivet område kan gives som Område- eller SumOmråde-parameter. For eksempel, hvis kolonnerne i ovenstående tabel er navngivet "Produktnavn", "Salg" og "Indtægter", vil funktionen returnere 150. Denne funktion virker kun som beskrevet her, hvis du har defineret navne på kolonnerne med dialogen Definér navne.

#### Reference til en celle som kriterium

Hvis du har brug for at ændre et kriterium enkelt, kan du specificere det i en separat celle og bruge en reference til denne celle i betingelsen for SUM.HVIS-funktionen. For eksempel:

=SUM.HVIS(A2:A6;E2;C2:C6)

Hvis E2 = pen vil funktionen returnere 85, fordi referencen til cellen er erstattet med dens indhold.

Relaterede emner

Wiki-side for funktionen SUM.HVIS (på engelsk: SUMIF).

SUM (samme navn på engelsk), SUM.FLERE.HVIS (på engelsk: SUMIFS)

TÆL.HVIS (på engelsk: COUNTIF), TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, Funktionen MIDDEL.FLERE.HVIS (på engelsk: AVERAGEIFS

Liste over regulære udtryk