Função CONTAR.SE.S

Conteúdo

# COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

Esta função está disponível desde o LibreOffice 4.0.

### Sintaxe

COUNTIFS(Range; Criterion[; Range2; Criterion2][; ... ; [Range127; Criterion127]])

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion1: A criterion is a text expression computed from a single cell Reference, Formula, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

- A number or logical value. A matching cell content equals the number or logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Note: "=0" does not match empty cells.

  For = and <>, if the value is not empty and can not be interpreted as a number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

Ao usar funções onde um ou mais argumentos são textos que representem uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Contudo, se mudar de configuração regional e o separador decimal não for o ponto, a expressão regular será utilizada. Para forçar a avaliação da expressão regular em vez de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número como, por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".

Range, Range2, ... and Criterion, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

A função pode ter até 255 argumentos, significando que pode haver 127 intervalos de critérios e critérios correspondentes.

Se a célula contiver VERDADEIRO, será tratada como 1 e se contiver FALSO, será tratada como 0 (zero).

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).

### Exemplos

Considere a seguinte tabela

| A | B | C
1 | Nome do produto | Sales | Revenue
2 | pencil | 20 | 65
3 | pen | 35 | 85
4 | caderno | 20 | 190
5 | book | 17 | 180
6 | pencil-case | not | not

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

#### Utilização

=CONTAR.SE.S(B2:B6;">=20")

Conta o número de linhas do intervalo B2:B6 cujo valor seja maior ou igual a 20. Devolve 3, uma vez que a quinta e a sexta linha não cumprem os critérios.

=CONTAR.SE.S(B2:B6;">=20";C2:C6;">70")

Conta o número de linhas do intervalo C2:C6 cujo valor é maior que 70 e que correspondem às células de B2:B6 com valores maiores ou iguais a 20. Devolve 2, uma vez que a segunda, a quinta e a sexta linha não cumprem, pelo menos, um dos critérios.

#### Utilizar expressões regulares e funções incorporadas

For these examples to work as described, make sure that Enable regular expressions in formulas is selected in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

=CONTAR.SE.S(B2:B6;"[:alpha:]*")

Conta o número de linhas do intervalo B2:B6 que apenas possuem letras do alfabeto. Devolve 1, uma vez que apenas a sexta linha cumpre o critério.

=CONTAR.SE.S(B2:B6;">"&MÍNIMOB2:B6);B2:B6;"<"&MÁXIMO(B2:B6))

Conta o número de linhas no intervalo B2:B6, exceto os valores máximo e mínimo. Devolve 2 uma vez que a terceira, a quinta e a sexta linha não cumprem, pelo menos, um dos critérios.

=CONTAR.SE.S(A2:A6;"pen.*";B2:B6;"<"&MÁXIMO(B2:B6))

Conta o número de linhas que correspondam a todos os valores do intervalo A2:A6 que começam com as letras "pen" e todas as células do intervalo B2:B6, exceto seu máximo. Devolve 1 porque apenas a segunda linha cumpre todos os critérios.

#### Referência a uma célula como critério

Se quiser alterar o critério facilmente, pode especificar o critério numa célula distinta e utilizar uma referência a esta célula como condição da função CONTAR.SE.S. Por exemplo, a função acima pode ser escrita da seguinte forma:

=CONTAR.SE.S(A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2 = pen, a função devolve 1, uma vez que a ligação à célula é substituída pelo seu conteúdo.

Tópicos relacionados

COUNTIFS wiki page.

CONTAR, CONTAR.SE, CONTAR.VAZIO, CONTAR.VAL

COUNTIFS, MINIFS, função MÁXIMO.SE.S, MÉDIA.SE.S, SUMIFS

Lista de expressões regulares