Содержимое

# Функции электронных таблиц

Этот раздел содержит описание функций электронных таблиц, а также примеры.

Доступ к этой команде

Вставка - Функция - Тип Электронная таблица

## ТИП.ОШИБКИ

Возвращает значение конкретной ошибки, либо #Н/Д, если ошибка отсутствует.

## СТИЛЬ

Применяет стиль к ячейке, содержащей формулу.

## DDE

Возвращает результат для ссылки DDE. Если содержимое диапазона или раздела изменилось, возвращаемое значение также меняется. Чтобы просмотреть обновлённые ссылки, следует перезагрузить электронную таблицу или выбрать команду Правка - Ссылки. Межплатформенные ссылки, например, запрещены ссылки из установки LibreOffice, запущенной в ОС Windows, на документ, созданный в ОС Linux.

#### Синтаксис

DDE("Сервер"; "Файл"; "Диапазон" [; Режим])

Сервер: имя приложения сервера. Приложения LibreOffice имеют имя сервера «soffice».

Файл: полное имя файла, включая путь.

Диапазон: область, содержащая данные для вычисления.

Режим: необязательный параметр для управления методами преобразования данных в числа на сервере DDE.

Режим | Результат
--- | ---
0 или отсутствует | Формат числа из стиля ячейки «По умолчанию»
1 | Данные всегда преобразуются в стандартный формат для английского языка (США)
2 | Данные извлекаются в виде текста; преобразование в числа не выполняется

#### Пример

=DDE("soffice";"c:\office\document\data1.ods";"лист1.A1") считывает содержимое ячейки A1 на Листе 1 электронной таблицы LibreOffice Calc data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Девиз дня") возвращает девиз в ячейке, содержащей данную формулу. Сначала в документ motto.odt, содержащий текст девиза, необходимо ввести строку и определить её в качестве первой строки раздела под именем Девиз дня (в LibreOffice Writer с помощью меню Вставка - Раздел). При внесении изменений в девиз (и сохранении) в документе LibreOffice Writer, девиз обновляется во всех ячейках LibreOffice Calc, в которых задана эта ссылка DDE.

## АДРЕС

Возвращает адрес (ссылку) ячейки в виде текста в соответствии с указанными номерами строки и столбца. Можно выбрать отображение адреса как абсолютного (например, $A$1), относительного (A1) или смешанного типа (A$1 или $A1). Можно также указать имя листа.

Для функциональной совместимости функции АДРЕС и ДВССЫЛ поддерживают необязательный параметр, который позволяет указать необходимость использования нотации R1C1 вместо обычной нотации A1.

В функции АДРЕС этот параметр вставляется в качестве четвёртого параметра, смещая при этом необязательный параметр имени листа на пятое место.

В функции ДВССЫЛ этот параметр добавляется в качестве второго параметра.

В обеих функциях, если аргумент вставлен со значением 0, используется нотация R1C1. Если аргумент не используется или его значение не равно нулю, используется нотация A1.

Если используется нотация R1C1, функция АДРЕС возвращает строки адреса, используя в качестве разделителя имён листов восклицательный знак «!», а функция ДВССЫЛ ожидает, что в качестве разделителя имён листов будет использоваться восклицательный знак. В нотации А1 обе функции по-прежнему используют точку «.» в качестве разделителя имён листов.

При открытии документов формата ODF 1.0/1.1, функции АДРЕС, которые указывают имя листа в качестве четвёртого параметра, сместят имя этого листа до пятого параметра. Будет вставлен новый четвёртый параметр со значением 1.

Если при сохранении документа в формате ODF 1.0/1.1 в функциях АДРЕС имеется четвёртый параметр, этот параметр будет удалён.

Не сохраняйте электронную таблицу в старом формате ODF 1.0/1.1, если четвёртый параметр функции АДРЕС использовался со значением 0.

Функция ДВССЫЛ сохраняется без преобразования в формат ODF 1.0/1.1. Если имеется второй параметр, более старая версия Calc возвратит для этой функции ошибку.

#### Синтаксис

АДРЕС(Строка; Столбец [; Абс [; A1 [; "Лист"]]])

Строка: номер строки для ссылки на ячейку.

Столбец: номер столбца для ссылки на ячейку (число, а не буква).

Абс: определяет тип ссылки:

1: абсолютная ($A$1)

2: абсолютная ссылка на строку, относительная ссылка на столбец (A$1)

3: строка (относительная), столбец (абсолютная) ($A1)

4: относительная (A1)

A1 (необязательный параметр): если для этого параметра установлено значение 0, то используется нотация R1C1. Если же этот параметр отсутствует или имеет значение отличное от 0, то используется нотация A1.

Лист: имя листа. Заключается в двойные кавычки.

### Пример:

=АДРЕС(1; 1; 2; ;"Лист2") возвращает следующий результат: Лист2.A$1

Если представленная выше формула находится в B2 на текущем листе, а ячейка A1 на листе 2 содержит значение -6, то можно непрямо ссылаться на ячейку с помощью функции в B2 путём ввода=ABS(ДВССЫЛ(B2)). Результат будет представлен в виде абсолютного значения ссылки на ячейку, указанную в B2, которая в данном случае имеет значение 6.

## ВПР

Вертикальный поиск со ссылкой на смежные ячейки вправо. Эта функция проверяет наличие конкретного значения в первом столбце массива. В результате функция возвращает значение в той же строке столбца с именем Индекс. Если параметр Отсортировано пропущен или установлен в значение ИСТИНА, либо один, предполагается, что данные отсортированы в восходящем порядке. В этом случае, если точное совпадение для Строка поиска не найдено, возвращается последнее значение, которое меньше условия поиска. Если же параметр Отсортировано установлен в значение ЛОЖЬ или ноль, то необходимо найти точное совпадение, в противном случае вместо результата будет выведена Ошибка: Значение недоступно. Поэтому при значении ноль сортировать данные в восходящем порядке не требуется.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Синтаксис

=ВПР(Критерий поиска; Массив; Индекс [; Сортированный диапазон поиска])

Критерий поиска содержит значение любого типа, поиск которого производится в первом столбце массива.

Массив: ссылка, которая должна содержать число столбцов, указанное в аргументе Индекс.

Индекс: количество столбцов в массиве, который содержит возвращаемое значение. Первому столбцу соответствует номер 1.

Сортированный диапазон поиска: необязательный параметр, указывающий на то, что в первом столбце массива вместо обычных значений содержатся границы диапазона. В этом режиме, поиск возвращает значение строки, где в первом столбце значение будет равно или меньше Критерия поиска. Например, строка может содержать даты изменения налоговой ставки, и эти значения содержат даты начала периода действия конкретного значения налоговой ставки. Таким образом, выполняя поиск по дате, которая отсутствует в первом столбце массива, но попадает между существующими границами дат, выдаст наименьшую из них, позволяя найти данные, имевшие силу на искомую дату. Введите логическое значение ЛОЖЬ или ноль, если первый столбец не является списком границ диапазона. Если этот параметр содержит значение ИСТИНА или отсутствует, первый столбец массива необходимо сортировать в восходящем порядке. Поиск по сортированным столбцам может выполняться намного быстрее и функция всегда возвращает значение, даже если не было точного совпадения искомой величины, если оно больше, чем наименьшее значение сортируемого списка. В несортированном списке искомое значение должно иметь точное совпадение.В противном случае функция будет возвращать #Н/Д с сообщением: Ошибка: Значение недоступно.

Обработка пустых ячеек

#### Пример

Требуется ввести число блюда меню в ячейку A1, а имя блюда должно быть представлено в виде текста в смежную ячейку (B1). Соответствие Имени Номеру содержится в массиве D1:E100. D1 содержит 100, E1 содержит имя Овощной суп, и так далее, для 100 пунктов меню. Числа в столбце D отсортированы в восходящем порядке; поэтому, параметр Отсортировано необязателен.

Введите следующую формулу в ячейку B1:

=ВПР(A1; D1:E100; 2)

При вводе номера в ячейку A1 в ячейке B1 будет отображен соответствующий текст, который содержится во втором столбце массива D1:E100. При вводе несуществующего номера в ячейке отображается текст для следующего номера. Для предотвращения такого поведения задайте последнему параметру формулы значение ЛОЖЬ, чтобы при вводе несуществующего номера отображалось сообщение об ошибке.

## ВЫБОР

Эта функция использует индекс, чтобы вернуть значение из списка, содержащего до 30 значений.

#### Синтаксис

ВЫБОР(Индекс; Значение 1 [; Значение 2 [; ... [; Значение 30]]])

Индекс: ссылка или число в диапазоне от 1 до 30, указывающее на значение, которое требуется извлечь из списка.

Значение 1, Значение 2, ..., Значение 30: список значений, вводимых в виде ссылки на ячейку или в виде отдельных значений.

#### Пример

=ВЫБОР(A1; B1; B2; B3; "Сегодня"; "Вчера"; "Завтра"): в данном примере функция возвращает содержимое ячейки B2 для A1 = 2; для A1 = 4 функция возвращает текст «Сегодня».

## ГИПЕРССЫЛКА

При щелчке ячейки с функцией ГИПЕРССЫЛКА открывается соответствующая гиперссылка.

При использовании необязательного параметра Значение ячейки формула локализует URL-адрес, а затем отображает текст или число.

Чтобы открыть ячейку с гиперссылкой с помощью клавиатуры, выделите ячейку, нажмите клавишу F2, чтобы включить режим редактирования, поместите курсор в начало гиперссылки, нажмите сочетание клавиш SHIFT+F10, а затем выберите команду Открыть гиперссылку.

#### Синтаксис

ГИПЕРССЫЛКА("URL" [; Значение ячейки])

URL: указывает объект ссылки. Необязательный параметр Значение ячейки представляет собой текст или число, которые отображаются в ячейке и будут возвращены в качестве результата. Если параметр Значение ячейки не указан, URL отображается в тексте ячейки и будет возвращён в качестве результата.

Для пустых ячеек и элементов матрицы возвращается 0.

#### Пример

=ГИПЕРССЫЛКА("http://www.example.org") отображает текст «http://www.example.org» в ячейке и при щелчке выполняет переход по гиперссылке http://www.example.org.

=ГИПЕРССЫЛКА("http://www.example.org";"Щёлкните здесь") отображает текст «Щёлкните здесь» в ячейке и при щечке выполняет переход по гиперссылке http://www.example.org.

=ГИПЕРССЫЛКА("http://www.example.org";12345) отображает число 12345 и при щелчке выполняет переход по гиперссылке http://www.example.org.

=ГИПЕРССЫЛКА($B4) в этом случае ячейка B4 содержит http://www.example.org. Функция добавляет http://www.example.org в URL-адрес ячейки с гиперссылкой и возвращает тот же текст, который используется в качестве результата выполнения формулы.

=ГИПЕРССЫЛКА("http://www.";"Щёлкните ") & "example.org" отображает текст «Щёлкните example.org» в ячейке, а при щелчке выполняет переход по гиперссылке http://www.example.org.

=ГИПЕРССЫЛКА("#Лист1.A1";"Перейти вверх") отображает текст «Перейти вверх» и переходит на ячейку Лист1.A1 в данном документе.

=ГИПЕРССЫЛКА("file:///C:/writer.odt#Specification";"Перейти к закладке Writer") отображает текст «Перейти к закладке Writer», загружает заданный текстовый документ и переходит к закладке «Specification».

=ГИПЕРССЫЛКА("file:///C:/Documents/";"Открыть папку Documents") отображает текст «Открыть папку Documents» и показывает содержимое папки с помощью стандартного менеджера файлов данной операционной системы.

Функция пытается соответствовать специфике системы. Например, «c:\path to\file.ext» в Windows можно правильно интерпретировать в виде «file:///c:/path%20to/file.ext», а «..» направит в родительский каталог документа.

## ГПР

Служит для поиска значения и ссылки на ячейки в выделенной области. Эта функция проверяет первую строку массива на наличие определённого значения. Функция возвращает значение в тот же столбец в строку массива в соответствии с её номером в индексе.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Синтаксис

ГПР(Критерий поиска; Массив; Индекс [; Сортированный диапазон поиска])

Объяснение параметров, см. на: ГПР (столбцы и строки меняются местами)

Обработка пустых ячеек

#### Пример

Допустим, была создана небольшая таблица базы данных, занимающая диапазон ячеек A1:DO4 и содержащая базовую информацию о 118 химических элементах. Первый столбец содержит заголовки строк «Элемент», «Символ», «Атомный номер» и «Относительная атомная масса». Последующие столбцы содержат соответствующую информацию по каждому элементу, в порядке слева направо по атомным номерам. Например, ячейки B1:B4 содержат «Водород», «H», «1» и «1.008», в то время как ячейки DO1:DO4 содержат «Оганесон»,«Og», «118» и «294».

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Элемент | Водород | Гелий | Литий | ... | Оганесон
2 | Символ | H | He | Li | ... | Og
3 | Атомный номер | 1 | 2 | 3 | ... | 118
4 | Относительная атомная масса | 1.008 | 4.0026 | 6.94 | ... | 294

=ГПР("Свинец"; $A$1:$DO$4; 2; 0) возвращает «Pb», символ свинца.

=ГПР("Золото"; $A$1:$DO$4; 3; 0) возвращает 79, атомный номер золота.

=ГПР("Углерод"; $A$1:$DO$4; 4; 0) возвращает 12,011, относительная атомная масса углерода.

## ДВССЫЛ

Возвращает ссылку в виде текстовой строки. Эту функцию можно также использовать для получения области соответствующей строки.

Эта функция всегда пересчитывается при пересчёте.

Для функциональной совместимости функции АДРЕС и ДВССЫЛ поддерживают необязательный параметр, который позволяет указать необходимость использования нотации R1C1 вместо обычной нотации A1.

В функции АДРЕС этот параметр вставляется в качестве четвёртого параметра, смещая при этом необязательный параметр имени листа на пятое место.

В функции ДВССЫЛ этот параметр добавляется в качестве второго параметра.

В обеих функциях, если аргумент вставлен со значением 0, используется нотация R1C1. Если аргумент не используется или его значение не равно нулю, используется нотация A1.

Если используется нотация R1C1, функция АДРЕС возвращает строки адреса, используя в качестве разделителя имён листов восклицательный знак «!», а функция ДВССЫЛ ожидает, что в качестве разделителя имён листов будет использоваться восклицательный знак. В нотации А1 обе функции по-прежнему используют точку «.» в качестве разделителя имён листов.

При открытии документов формата ODF 1.0/1.1, функции АДРЕС, которые указывают имя листа в качестве четвёртого параметра, сместят имя этого листа до пятого параметра. Будет вставлен новый четвёртый параметр со значением 1.

Если при сохранении документа в формате ODF 1.0/1.1 в функциях АДРЕС имеется четвёртый параметр, этот параметр будет удалён.

Не сохраняйте электронную таблицу в старом формате ODF 1.0/1.1, если четвёртый параметр функции АДРЕС использовался со значением 0.

Функция ДВССЫЛ сохраняется без преобразования в формат ODF 1.0/1.1. Если имеется второй параметр, более старая версия Calc возвратит для этой функции ошибку.

#### Синтаксис

ДВССЫЛ(Ссылка [; A1])

Ссылка: ссылка на ячейку или область (в текстовой форме), для которой возвращается содержимое.

A1 (необязательный параметр): если для этого параметра установлено значение 0, то используется нотация R1C1. Если этот параметр отсутствует или имеет значение, отличное от 0, то используется нотация A1.

При открытии электронной таблицы Excel, использующей непрямые адреса, рассчитываемые из строковых функций, адреса листа не будут транслироваться автоматически. Например, адрес Excel в ДВССЫЛ("[имя файла]имя листа!"&B1) не конвертируется в адрес Calc в ДВССЫЛ("имя файла#имя листа."&B1).

#### Пример

=ДВССЫЛ(A1) возвращает значение 100, если ячейка A1 содержит ссылку на ячейку C108, а ячейка C108 содержит значение 100.

=СУММ(ДВССЫЛ("a1:" & АДРЕС(1; 3))) суммирует содержимое ячеек в области от A1 до ячейки, адрес которой определён в строке 1 и столбце 3. Таким образом, вычисляется сумма диапазона A1:C1.

См. также

Страница wiki функции INDIRECT.

## ДСВТ

Функция ДСВТ возвращает значение результата из сводной таблицы. Значение адресуется с помощью имён поля и элемента, поэтому оно остаётся действительным даже при изменении структуры сводной таблицы.

#### Синтаксис

Можно использовать два разных синтаксиса:

ДСВТ(Поле данных; Сводная таблица[; Поле 1; Элемент 1][; ... [Поле 126; Элемент 126]])

или

ДСВТ(Сводная таблица; Ограничения)

Второй синтаксис используется при наличии двух параметров, первый из которых является ячейкой или ссылкой на диапазон ячеек. Во всех других случаях применяется первый синтаксис. В Мастере функций также отображается первый синтаксис.

### Первый синтаксис

Поле данных: строка для выбора одного из полей данных сводной таблицы. Эта строка может содержать имя исходного столбца или имя поля данных, отображаемое в таблице (например, «Сумма – Сбыт»).

Сводная таблица: ссылка на ячейку или диапазон ячеек, расположенный в сводной таблице или содержащий сводную таблицу. Если диапазон ячеек содержит несколько сводных таблиц, то используется таблица, созданная последней.

При отсутствии пар Имя поля n/Элемент n возвращается общий итог. В противном случае для каждой пары добавляется ограничение, которому должен удовлетворять результат. Имя поля n является именем поля из сводной таблицы. Элемент n является именем элемента из этого поля.

Если сводная таблица содержит только одно значение результата, которое удовлетворяет всем ограничениям, или результат промежуточного итога, являющийся суммой всех сопоставимых значений, то возвращается этот результат. При отсутствии результата сопоставления или при нескольких результатах без промежуточного итога возвращается ошибка. Эти условия относятся к результатам, включённым в сводную таблицу.

Если исходные данные содержат записи скрытые настройками сводной таблицы, то они игнорируются. Порядок пар «имя поля/элемент» не имеет значения. Регистр имён полей и элементов не учитывается.

Если для фильтра не задано никаких ограничений, неявно используется выбранное значение поля. При указании ограничения для фильтра оно должно совпадать с выбранным значением поля, либо возвращается ошибка. Фильтры представляют собой поля, расположенные сверху слева сводной таблицы, заполняемой в области «Фильтры» диалога разметки сводной таблицы. От каждого фильтра можно выбрать элемент (значение), что означает включение только этого элемента в вычисление.

Значения промежуточных итогов из сводной таблицы используются только для функции «Авто» (кроме значений, включённых в ограничения, см. Второй синтаксис ниже).

### Второй синтаксис

Сводная таблица: аналогично первому варианту синтаксиса.

Ограничения: список значений, разделённых пробелами. Элементы списка могут заключаться в кавычки (одиночные). Вся строка заключается в двойные кавычки (за исключением случая, когда указывается ссылка на строку из другой ячейки).

Одна из записей может быть именем поля данных. Если сводная таблица содержит только одно поле данных, имя поля данных можно не указывать; в противном случае присутствие его необходимо.

Все остальные записи формы содержат ограничение в виде Поле[Элемент] (с символами «[» и «]»), либо только Элемент, если элемент имеет уникальное имя среди всех полей сводной таблицы.

Имя функции может быть добавлено в виде Поле[Элемент;Функция], при котором ограничение будет совпадать только со значениями промежуточных итогов, использующих эту функцию. Допустимые имена функций: СУММ, СЧЁТ, СРЗНАЧ, МАКС, МИН, ПРОИЗВ, СЧЁТ(только числа), СТОТКЛ(выборка), СТОТКЛГ(совокупность) без учёта регистра.

## ИНДЕКС

ИНДЕКС возвращает ссылку, значение или массив значений из диапазона ссылок, указанных в виде индекса стоки и столбца, либо индексов массива строк и массива столбцов, а также необязательный индекс диапазона.

ИНДЕКС() возвращает ссылку при наличии у аргумента одной или нескольких ссылок. При использовании функции в ячейке в форме =ИНДЕКС() считываются и отображаются значения по ссылке. Когда ИНДЕКС() используется в качестве аргументов других функций, =ФУНКЦИЯ(ИНДЕКС()...), функция получает ссылку, которую возвращает ИНДЕКС(). Возвращение ссылки отличается от возвращения массива значений для различного использования в функциях.

#### Синтаксис

ИНДЕКС(Ссылка [; [Строка] [; [Столбец] [; Диапазон]]])

Ссылка: вводится непосредственно или в виде указания именованного диапазона. Если ссылка состоит из нескольких диапазонов, необходимо заключить список ссылок или именованных диапазонов в скобки, либо использовать тильду (~) оператора конкатенации диапазонов, либо задать именованный диапазон с содержанием нескольких областей.

Строка (необязательно): представляет собой строку или массив индексов строк в диапазоне ссылок, для которого необходимо вернуть значение. В случае передаче нуля или при отсутствии указания (без указания строки) возвращаются все ссылки на строки.

Столбец (необязательно): представляет собой столбец или массив индексов столбцов в диапазоне ссылок, для которого необходимо вернуть значение. В случае передачи нуля или при отсутствии указания (без указания столбца) возвращаются все ссылки на столбцы.

Если и Строка, и Столбец будут либо пропущены, либо определены как массивы индексов, функция ИНДЕКС должна вводится в качестве функции массива.

Диапазон (необязательно): представляет индекс поддиапазона при указании на составной диапазон, значение по умолчанию 1.

#### Пример

{=ИНДЕКС({1,3,5;7,9,10},{2;1},1)} возвращает массив из 2 строк, содержащий 7 и 1. Индекс строки {2;1} получает сначала строку 2, а затем строку 1. Индекс столбца 1 получает первый столбец.

{=ИНДЕКС(D3:G12,{1;2;3;4},{3,1})} возвращает массив размером 4 строки на 2 столбца. Массив индекса строк {1;2;3;4} берёт строки с 3 по 6, а {3;1} берёт третий (F) и первый столбцы (D). Столбцы 1 и 3 по исходной ссылке подставляются в итоговый массив.

=INDEX(Цены; 4; 1) возвращает значение для строки 4 и столбца 1 из диапазона в базе данных, определённого в меню Данные – Определить как Цены.

=ИНДЕКС(Сумма X;4;1) возвращает значение из диапазона Сумма X в строке 4 и столбце 1, согласно определению в меню Лист - Именованные диапазоны и выражения - Задать.

{=ИНДЕКС(A1:B6;1)} возвращает значения первой строки A1:B6. Введите формулу в виде формулы массива.

{=ИНДЕКС(A1:B6;0;1)} возвращает значения первого столбца диапазона A1:B6. Введите формулу в виде формулы массива.

=INDEX(A1:B6; 1; 1) возвращает значение левой верхней ячейки диапазона A1:B6.

{=ИНДЕКС((A1:B6;C1:D6);0;0;2)} возвращает значения второго диапазона C1:D6 из нескольких диапазонов. Введите формулу в виде формулы массива.

См. также

Страница wiki функции ИНДЕКС.

## ЛИСТ

Возвращает номер листа по ссылке, либо строке, содержащей имя листа. Если не вводить никаких параметров, то результатом работы функции будет номер листа электронной таблицы, содержащий данную формулу.

#### Синтаксис

ЛИСТ([Ссылка])

Ссылка (необязательный параметр): ссылка на ячейку или область, либо строка с именем листа.

#### Пример

=ЛИСТ(Лист2.A1) возвращает 2, если Лист2 является вторым листом в электронной таблице.

=ЛИСТ("Лист3") возвращает 3, если Лист3 является третьим листом в электронной таблице.

## ЛИСТЫ

Служит для определения количества листов для ссылки. Если параметры не заданы, возвращается количество листов в текущем документе.

#### Синтаксис

ЛИСТЫ([Ссылка])

Ссылка: ссылка на лист или область. Этот параметр не является обязательным.

#### Пример

=SHEETS(Sheet1.A1:Sheet3.G12) возвращает значение 3, если листы Лист1, Лист2 и Лист3 стоят в указанной последовательности.

## ОБЛАСТИ

Возвращает количество отдельных диапазонов, входящих в составной диапазон. Диапазон может состоять из смежных ячеек или одной ячейки.

В функцию передаётся только один аргумент. При определении составных диапазонов их необходимо заключать в дополнительные скобки. Составные диапазоны указываются через точку с запятой (;), но этот знак автоматически преобразуется в оператор «тильда» (~). Тильда используется для объединения диапазонов.

#### Синтаксис

ОБЛАСТИ(Ссылка)

Ссылка. Ссылка на ячейку или диапазон ячеек.

#### Пример

=ОБЛАСТИ((A1:B3; F2; G1)) возвращает значение 3, поскольку это ссылка на три ячейки или области. После ввода выполняется преобразование в =ОБЛАСТИ((A1:B3~F2~G1)).

=ОБЛАСТИ(Все) возвращает значение 1, если в окне Данные – определить диапазон была определена область с именем «Все».

## ПОИСКПОЗ

Возвращает относительную позицию в массиве элемента, который совпадает с заданным значением. Функция возвращает позицию значения, найденного в массиве, в виде числа.

#### Синтаксис

ПОИСКПОЗ(Критерий поиска; Массив [; Тип])

Критерий поиска: значение, поиск которого осуществляется в массиве, состоящем из одной строки или одного столбца.

Массив: искомая ссылка. Это может быть одна строка или столбец, либо часть одной строки или столбца.

Тип: может принимать значения 1, 0 или -1. Если этот необязательный параметр имеет значение 1, либо не указан, то предполагается, что значения в первом столбце массива отсортированы по возрастанию. Если этому параметру присвоено значение -1, то предполагается, что значения столбца отсортированы по убыванию. Эта функция соответствует аналогичной функции в Microsoft Excel.

Если Тип = 0, найдены только точные совпадения. Если найдено более одного совпадения с критериями поиска, то функция возвращает индекс первого совпавшего значения. Регулярные выражения (если включены в параметрах вычисления) или подстановочные знаки (если включены в параметрах вычисления) можно применять только если Тип = 0.

Если Тип = 1 или третий параметр отсутствует, то возвращается индекс последнего значения, меньшего или равного условиям поиска. Для Тип = -1, возвращается индекс большего или равного последнего значения.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Пример

=MATCH(200; D1:D100) выполняет поиск значения 200 в области D1:D100, отсортированной по столбцу D. По достижении этого значения возвращается номер соответствующей строки. Если найденное значение больше искомого, возвращается номер предыдущей строки.

## ПРОСМОТР

Возвращает содержимое ячейки из однострочного или одностолбцового диапазона. Заданное значение (с тем же индексом) можно вернуть в другой столбец и строку. В противоположность ВПР и ГПР, векторы просмотра и результата могут находится в разных местах; они необязательно должны быть смежными. Вектор просмотра для функции ПРОСМОТР может быть дополнительно отсортирован в восходящем порядке, иначе результаты поиска не будут представлять никакого смысла.

Если с помощью функции LOOKUP соответствия критерию поиска найти не удаётся, то будет использовано самое большое значение в векторе просмотра, которое меньше или равно критерию поиска.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Синтаксис

ПРОСМОТР(Критерий поиска; Вектор поиска [; Результирующий вектор])

Критерий поиска: просматриваемое значение любого типа; вводится либо напрямую, либо в виде ссылки.

Вектор поиска: область поиска, состоящая из отдельной строки или столбца.

Вектор результата: другой диапазон из одной строки или одного столбца, из которого извлекается результат функции. Функция возвращает ячейку вектора результата с тем же индексом, что и экземпляр, найденный в векторе просмотра.

Обработка пустых ячеек

#### Пример

=LOOKUP(A1; D1:D100; F1:F100) позволяет выполнить поиск соответствующей ячейки в диапазоне D1:D100 для числа, указанного в ячейке A1. Для найденного экземпляра определяется индекс, например, 12-я ячейка в этом диапазоне. Затем содержимое 12-й ячейки возвращается в виде значения функции (в векторе результата).

## СМЕЩ

Возвращает значение смещения ячейки от заданной точки на определённое число строк и столбцов.

Эта функция всегда пересчитывается при пересчёте.

#### Синтаксис

СМЕЩ(Ссылка; Строки; Столбцы [; Высота [; Ширина]])

Ссылка: ссылка, начиная с которой функция выполняет поиск новой ссылки.

Строки: количество строк, на которое ссылка была смещена вверх (отрицательное значение) или вниз. Чтобы остаться в той же строке необходимо использовать значение 0.

Строки: количество строк, на которое ссылка была смещена вверх (отрицательное значение) или вниз.

Высота (необязательный параметр): высота области, которая начинается с новой позиции ссылки.

Ширина (необязательный параметр): ширина области, которая начинается с новой позиции ссылки.

Аргументы Строки и Столбцы не должны приводить к нулевой или отрицательной начальной строке или столбцу.

Аргументы Высота и Ширина не должны приводить к нулевому или отрицательному количеству строк или столбцов.

В функциях LibreOffice Calc параметры, отмеченные, как «необязательные» могут быть пропущены, только если нет параметров, идущих после. Например, в функции с четырьмя параметрами, в которой последние два параметра «необязательные», вы можете пропустить 4-й параметр или 3-й и 4-й, но нельзя пропустить только 3-й параметр.

#### Пример

=СМЕЩ(A1; 2; 2) возвращает значение ячейки C3 (ячейка A1 смещается вниз на две строки и два столбца). Если ячейка C3 содержит значение 100, то эта функция возвращает значение 100.

=СМЕЩ(B2:C3; 1; 1) возвращает ссылку на диапазон B2:C3, перемещённый на 1 строку вниз и на один столбец вправо (C3:D4).

=СМЕЩ(B2:C3; -1; -1) возвращает ссылку на диапазон B2:C3, поднятый на 1 строку и сдвинутый влево на 1 столбец (A1:B2).

=СМЕЩ(B2:C3; 0; 0; 3; 4) возвращает ссылку на диапазон B2:C3, размер которого изменён на 3 строки и 4 столбца (B2:E4).

=СМЕЩ(B2:C3; 1; 0; 3; 4) возвращает ссылку на диапазон B2:C3, смещённый вниз на одну строку и изменивший размер на 3 строки и 4 столбца (B2:E4).

=СУММ(СМЕЩ(A1; 2; 2; 5; 6)) позволяет определить общую площадь области, которая начинается с ячейки C3 и имеет в своём составе 5 строк в высоту и 6 столбцов в ширину (область=C3:H7).

Если даны Ширина или Высота, то функция СМЕЩ возвращает ссылку диапазона ячеек. Если Ссылка ссылается на одну ячейку и отсутствуют оба аргумента Ширина и Высота, то возвращается ссылка на одну ячейку.

## СТОЛБЕЦ

Возвращает номер столбца ссылки ячейки. Если ссылка является ячейкой, возвращается номер столбца ячейки; если параметр является областью ячейки, возвращаются соответствующие номера столбцов в виде одномерного массива, если формула введена в виде формулы массива. Если функция СТОЛБЕЦ с параметром ссылки на область не используется для формулы массива, то определяется только номер столбца первой ячейки в составе области.

#### Синтаксис

СТОЛБЕЦ([Ссылка])

Ссылка: ссылка на ячейку или область ячеек, для которой требуется определить номер первого столбца.

Если ссылка не указана, возвращается номер столбца для ячейки с формулой. LibreOffice Calc автоматически создаёт ссылку на текущую ячейку.

#### Пример

=COLUMN(A1) возвращает значение 1. Столбец A является первым столбцом в таблице.

=COLUMN(C3:E3) возвращает значение 3. Столбец C является третьим столбцом в таблице.

=COLUMN(D3:G10) возвращает значение 4, поскольку столбец D является четвёртым в таблице, а функция COLUMN не используется в качестве формулы массива. (В этом случае результатом всегда является первое значение массива.)

{=COLUMN(B2:B7)} и =COLUMN(B2:B7) возвращают значение 2, поскольку ссылка указывает только на столбец B, являющийся вторым столбцом в таблице. Поскольку для области, состоящей из одного столбца, можно извлечь только один номер столбца, формулу массива использовать необязательно.

=COLUMN() возвращает значение 3, если формула была введена в столбце C.

{=COLUMN(Rabbit)} возвращает массив с одной строкой (3, 4), если «Rabbit» является именованной областью (C1:D3).

## СТРОКА

Возвращает номер строки ссылки на ячейку. Если ссылка является ячейкой, то функция возвращает номер строки ячейки. Если ссылка является диапазоном ячеек, то функция возвращает соответствующие номера строк в одностолбцовом массиве, если формула была введена как формула массива. Если функция СТРОКА со ссылкой на диапазон не используется ни в одной формуле массива, то возвращается только номер строки первой ячейки диапазона.

#### Синтаксис

СТРОКА([Ссылка])

Ссылка: ячейка, область или имя области.

Если ссылка не указана, возвращается номер строки для ячейки, которая содержит формулу. LibreOffice Calc автоматически создаёт ссылку на текущую ячейку.

#### Пример

=ROW(B3) возвращает значение 3, поскольку ссылка указывает на третью строку таблицы.

{=ROW(D5:D8)} возвращает массив, состоящий из одного столбца (5, 6, 7, 8), поскольку ссылка указывает на строки с 5 по 8.

=ROW(D5:D8) возвращает значение 5, поскольку функция ROW не используется как формула массива, таким образом, возвращается только номер первой строки ссылки.

{=ROW(A1:E1)} и =ROW(A1:E1) возвращают значение 1, поскольку ссылка указывает только на строку 1 как на первую строку в таблице. (Поскольку для области, состоящей из одной строки, можно извлечь только один номер строки, формулу массива использовать необязательно.)

=ROW() возвращает значение 3, если формула была введена в строку 3.

{=ROW(Rabbit)} возвращает массив с одним столбцом (1, 2, 3), если «Rabbit» является именованной областью (C1:D3).

## ТИПОШИБКИ

Возвращает номер, соответствующий типу ошибки в другой ячейке. С помощью этого номера можно воспроизвести текст сообщения об ошибке.

If an error occurs, the function returns a logical or numerical value.

В строке состояния при щелчке по ячейке с ошибкой отображается стандартный код ошибки LibreOffice.

#### Синтаксис

ТИПОШИБКИ(Ссылка)

Ссылка: адрес ячейки с ошибкой.

#### Пример

Если в ячейке A1 отображается Ошибка:518, функция =ТИПОШИБКИ(A1) возвращает номер 518.

#### Техническая информация

Эта функция НЕ входит в стандарт Формата Open Document для офисных приложений (OpenDocument) v1.3. Часть 4: Формат пересчитываемой формулы (OpenFormula). Используемое пространство имён:

ORG.OPENOFFICE.ERRORTYPE

## ЧСТОЛБ

Возвращает количество столбцов для заданной ссылки.

#### Синтаксис

ЧСТОЛБ(Массив)

Массив: ссылка на диапазон ячеек, для которого требуется подсчитать общее количество столбцов. Аргументом также может являться отдельная ячейка.

#### Пример

=COLUMNS(B5) возвращает значение 1, поскольку ячейка содержит только один столбец.

=COLUMNS(A1:C5) возвращает значение 3. Диапазон содержит три столбца.

=COLUMNS(Rabbit) возвращает значение 2, если Rabbit — указанный диапазон (C1:D3).

## ЧСТРОК

Возвращает количество строк в массиве или ссылке.

#### Синтаксис

ЧСТРОК(Массив)

Массив: ссылка или именованная область, для которой требуется определить общее количество строк.

#### Пример

=ROWS(B5) возвращает значение 1, поскольку ячейка включает только одну строку.

=ROWS(A10:B12) возвращает значение 3.

=ROWS(Rabbit) возвращает значение 3, если «Rabbit» является именованной областью (C1:D3).

См. также

Функции по категориям