Innehåll

# Finansfunktioner del två

Så här använder du det här kommandot...

Infoga - Funktion - Kategori Ekonomi

Tillbaka till Finansfunktioner del ett

Till finansfunktionerna del 3

## AMORT

Returnerar under en given period betalningen på kapitalet för en investering som baseras på en periodisk och fast betalning och en fast ränta.

#### Syntax

PPMT(Rate; Period; NPer; PV [ ; FV [ ; Type ] ])

ränta är räntesatsen för en periods betalning.

P amorteringsperioden. P = 1 för den första perioden och P = Perioder för den sista perioden.

Perioder är det totala antalet perioder då annuiteter betalas.

Nuvärde är det nuvarande värdet i betalningssekvensen.

Slutvärde (valfritt) är det önskade (framtida) värdet.

Typ (valfritt) anger förfallodatumet. F = 1 för betalning vid periodens början, och F = 0 för betalning vid periodens slut.

I LibreOffice Calc-funktioner kan de parametrar som markeras som "valfria" bara utelämnas när inga efterföljande parametrar finns. I till exempel en funktion med fyra parametrar, där de två sista parametrarna markeras som "valfria", kan du utelämna parameter 4 eller parametrarna 3 och 4, men inte utelämna enbart parameter 3.

#### Example

Hur hög blir den periodiska månadsavgiften vid en årsränta på 8,75% över en period av 3 år? Värdet är 5 000 valutaenheter och betalas alltid i början av en period. Slutvärdet är 8 000 valutaenheter.

=BETALNING (8,75 %/12; 1; 36; 5000; 8000; 1) = -350,99 valutaenheter.

## BETALNING

Returnerar den periodiska betalningen för en annuitet med konstanta räntor.

#### Syntax

PMT(Rate; NPer; PV [ ; [ FV ] [ ; Type ] ])

ränta är räntesatsen för en periods betalning.

Perioder är det totala antalet perioder då annuiteter betalas.

Nuvärde är det nuvarande värdet av varje betalning.

Slutvärde (valfritt) är det slutliga värde (framtida värde) som ska ha uppnåtts när alla betalningar är gjorda.

Typ (valfritt) är förfallodatum för de periodiska betalningarna. Typ = 1 är betalning vid början av varje period och Typ = 0 är betalning vid slutet av varje period.

I LibreOffice Calc-funktioner kan de parametrar som markeras som "valfria" bara utelämnas när inga efterföljande parametrar finns. I till exempel en funktion med fyra parametrar, där de två sista parametrarna markeras som "valfria", kan du utelämna parameter 4 eller parametrarna 3 och 4, men inte utelämna enbart parameter 3.

#### Example

Hur stor är den regelbundna betalningen vid en räntesats på 1,99 % om betalningsperioden är 3 år och nuvärdet 25 000 valutaenheter? Det finns 36 månader som utgör 36 betalningsperioder, och räntan per betalningsperiod är 1,99 %/12.

=BETALNING(1,99 %/12;36;25000) = -715,96 valutaenheter. Den periodiska månatliga betalningen är alltså 715,96 valutaenheter.

## BRÅK

Konverterar en kurs som har angetts som ett decimaltal till ett blandat decimalbråk.

#### Syntax

BRÅK(DecimalDollar; Bråk)

DecimalDollar är ett decimaltal.

Bråk är ett helt tal som används som nämnare i decimalbråket.

#### Example

=BRÅK(1,125;16) konverterar till sextondelar. Resultatet är 1,02 för 1 plus 2/16.

=BRÅK(1,125;8) konverterar till åttondelar. Resultatet är 1,1 för 1 plus 1/8.

## DECTAL

Konverterar en kurs som har angetts som bråk till ett decimaltal.

#### Syntax

DECTAL(FractionalDollar; Bråk)

FractionalDollar är ett tal angivet som ett decimalbråk.

Bråk är ett helt tal som används som nämnare i decimalbråket.

#### Example

=DECTAL(1,02;16) står för 1 och 2/16. Detta returnerar 1,125.

=DECTAL(1,1;8) står för 1 och 1/8. Detta returnerar 1,125.

## KUMPRIS

Returnerar den kumulativa räntan som betalas för en investeringsperiod med en konstant ränta.

#### Syntax

KUMPRIS(Ränta; Perioder; Nuvärde; S; E; Typ)

ränta är räntesatsen för en periods betalning.

Perioder är betalningsperioden med det totala antalet perioder. PERIODER behöver inte vara ett heltalsvärde.

Nuvärde är det nuvarande värdet av varje betalning.

S är den första perioden.

E den sista perioden.

Typ är förfallodatumet för betalningen i början eller slutet av varje period.

#### Example

Hur stora är beloppen om årsräntan än 5,5 % under 36 månader? Kontantvärdet är 15 000 valutaenheter. Beloppen beräknas mellan den 10:e och den 18:e perioden. Förfallodatum är i slutet av perioden.

=KUMPRIS (5,5 %/12;36;15000;10;18;0) = -3669,74 valutaenheter. Avräkningsbeloppet för tiden mellan den tionde och den artonde perioden är 3669,74 valutaenheter.

## KUMPRIS_ADD

Beräknar det kumulativa inlösningsvärdet för ett lån under en period.

De funktioner vars namn slutar med _ADD eller _EXCEL2003 returnerar samma resultat som motsvarande funktioner i Microsoft Excel 2003 utan suffixen. Funktioner utan suffix ger resultat som är baserade på internationell standard.

#### Syntax

KUMPRIS_ADD(Ränta; Perioder; Nuvärde; StartPeriod; SlutPeriod; Typ)

Ränta är räntesatsen för en periods betalning.

Perioder är det totala antalet betalningsperioder. Räntan och PERIODER måste syfta på samma enhet och måste alltså båda beräknas på års- eller månadsbasis.

Nuvärde är det aktuella värdet.

StartPeriod är första betalningsperiod för beräkningen.

SlutPeriod är den sista betalningsperioden i beräkningen.

Typ är förfallodatumet för en betalning vid varje periods slut. (Typ = 0) eller vid periodens början (Typ = 1).

#### Example

Följande hypotekslån tas för ett hus:

Ränta: 9,00 procent per år (9%/12 = 0,0075), löptid: 30 år (betalningsperioder = 30 * 12 = 360), nuvärde: 125 000 valutaenheter.

Hur hög är amorteringen som du betalar det andra året (d.v.s. i perioderna 13 till 24)?

=KUMPRIS_ADD(0,0075;360;125000;13;24;0) returnerar -934,1071

Den första månaden betalar du följande amortering:

=KUMPRIS_ADD(0,0075;360;125000;1;1;0) returnerar -68,27827

## KUMRÄNTA

Beräknar de kumulativa räntebetalningarna, det vill säga den totala räntan, för en investering baserat på en konstant räntesats.

#### Syntax

KUMRÄNTA(Ränta; Perioder; Nuvärde; S; E; Typ)

ränta är räntesatsen för en periods betalning.

Perioder är betalningsperioden med det totala antalet perioder. PERIODER behöver inte vara ett heltalsvärde.

Nuvärde är det nuvarande värdet av varje betalning.

S är den första perioden.

E den sista perioden.

Typ är förfallodatumet för betalningen i början eller slutet av varje period.

#### Example

Hur stor blir ränteandelen vid en periodisk räntesats på 5,5 %, en periodisk tidsrymd på 2 år och ett nuvärde på 5 000 valutaenheter? Beräkningsperioden börjar med den 4:e och slutar med den 6:e perioden. Den periodiska betalningen förfaller i början av perioden.

=KUMRÄNTA(5,5%/12;24;5000;4;6;1) = -57,54 valutaenheter. Räntebetalningarna för tiden mellan den fjärde och den sjätte perioden är 57,54 valutaenheter.

## KUMRÄNTA_ADD

Beräknar den ackumulerade räntan för en period.

De funktioner vars namn slutar med _ADD eller _EXCEL2003 returnerar samma resultat som motsvarande funktioner i Microsoft Excel 2003 utan suffixen. Funktioner utan suffix ger resultat som är baserade på internationell standard.

#### Syntax

KUMRÄNTA_ADD(Ränta; Perioder; Nuvärde; StartPeriod; SlutPeriod; Typ)

Ränta är räntesatsen för en periods betalning.

Perioder är det totala antalet betalningsperioder. Räntan och PERIODER måste syfta på samma enhet och måste alltså båda beräknas på års- eller månadsbasis.

Nuvärde är det aktuella värdet.

StartPeriod är första betalningsperiod för beräkningen.

SlutPeriod är den sista betalningsperioden i beräkningen.

Typ är förfallodatumet för en betalning vid varje periods slut. (Typ = 0) eller vid periodens början (Typ = 1).

#### Example

Följande hypotekslån tas för ett hus:

Ränta: 9,00 procent per år (9 %/12 = 0,0075), löptid: 30 år (perioder = 30 * 12 = 360), nuvärde: 125 000 valutaenheter.

Vilket räntebelopp ska du betala det andra året (d.v.s. i perioderna 13 till 24)?

=KUMRÄNTA_ADD(0,0075;360;125000;13;24;0) returnerar -11135,23.

Hur mycket ränta måste du betala den första månaden?

=KUMRÄNTA_ADD(0,0075;360;125000;1;1;0) returnerar -937,50.

## LINAVSKR

Returnerar den rätlinjiga avskrivningen för en tillgång under en period. Avskrivningsbeloppet är konstant under avskrivningsperioden.

#### Syntax

LINAVSKR (Kostnad; Restvärde; Livslängd)

Kostnad är tillgångens anskaffningsvärde.

Restvärde är tillgångens restvärde vid livslängdens slut.

LL är avskrivningsperioden som bestämmer antalet perioder i avskrivningen av tillgången.

#### Example

En kontorsutrustning med ett anskaffningsvärde på 50 000 valutaenheter ska skrivas av årligen under 7 år. Restvärdet är uppskattat till 3 500 valutaenheter.

=LINAVSKR(50000;3,500;84) = 553,57 valutaenheter. Den periodiska månatliga avskrivningen på kontorsutrustningen är 553,57 valutaenheter.

## MLÖPTID

Beräknar den modifierade Macauley-löptiden i år för ett värdepapper med periodisk räntebetalning.

#### Syntax

MDURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Kupong är den årliga nominella räntesatsen (kupongräntesatsen)

Avkastning är den årliga avkastningen för värdepappret.

Frekvens är antalet räntebetalningar per år (1, 2 eller 4).

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

Ett värdepapper köptes 2001-01-01; förfallodatum är 2006-01-01. Den nominella räntesatsen är 8 %. Avkastningen är 9,0 %. Räntan betalas halvårsvis (frekvensen är 2). Hur lång är den modifierade löptiden om daglig ränteberäkning (bas 3) används?

=MDURATION("2001-01-01"; "2006-01-01"; 0.08; 0.09; 2; 3) returns 4.02 years.

## MODIR

Beräknar den modifierade avkastningsgraden för en serie investeringar.

#### Syntax

MODIR (Värden; Investering; Återinvesteringsränta

Värdenmotsvarar matrisen eller cellreferensen för celler vars innehåll motsvarar betalningarna.

Investering är räntesatsen för investeringarna (de negativa värdena i matrisen)

Återinvesteringsränta är räntesatsen för återinvesteringarna (de positiva värdena i matrisen)

#### Example

Om cellerna innehåller informationen A1 = -5, A2 = 10, A3 = 15, och A4 = 8, ett investeringsvärde på 0,5 och ett återinvensteringsvärde på 0,1 blir resultatet 94,16%.

## NETNUVÄRDE

Returns the present value of an investment based on a series of periodic cash flows and a discount rate. To get the net present value, subtract the cost of the project (the initial cash flow at time zero) from the returned value.

If the payments take place at irregular intervals, use the XNPV function.

#### Syntax

NPV(Rate; Number 1 [; Number 2 [; … [; Number 254]]])

Ränta är diskonteringsräntan för en period.

Number 1; Number 2; … ; Number 254 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

What is the net present value of periodic payments of 10, 20, 30 and -5 currency units with a discount rate of 8.75%. At time zero the costs were paid as -40 currency units.

=NPV(8.75%;10;20;30;-5) = 45.86 currency units. The net present value is the returned value minus the initial costs of 40 currency units, therefore 5.86 currency units.

## NOMAVK

Beräknar avkastningen från en säkerhet.

#### Syntax

YIELD(Settlement; Maturity; Rate; Price; Redemption; Frequency [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Ränta är räntesatsen per år.

Pris är värdepapprets pris (inköpspriset) per 100 valutaenheter av nominellt värde.

Inlösen är det nominella inlösningsvärdet per 100 valutaenheter.

Frekvens är antalet räntebetalningar per år (1, 2 eller 4).

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

Ett värdepapper köptes 1999-02-15; förfallodatum är 2007-11-15. Räntesatsen är 5,75 %. Priset är 95,04287 valutaenheter per 100 enheter nominellt värde, inlösningsvärdet är 100 enheter. Räntan betalas halvårsvis (frekvens = 2) och basen är 0. Hur hög är avkastningen?

=YIELD("1999-02-15"; "2007-11-15"; 0.0575 ;95.04287; 100; 2; 0) returns 0.065 or 6.50 per cent.

## NOMAVKDISK

Beräknar den årliga avkastningen på en icke räntebärande säkerhet.

#### Syntax

YIELDDISC(Settlement; Maturity; Price; Redemption [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Pris är värdepapprets pris (inköpspriset) per 100 valutaenheter av nominellt värde.

Inlösen är det nominella inlösningsvärdet per 100 valutaenheter.

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

Ett icke-räntebärande värdepapper köptes 1999-02-15. Det förfaller 1999-03-01. Priset är 99,795 valutaenheter per 100 enheter nominellt värde, inlösningsvärdet är 100 enheter. Basen är 2. Hur hög är avkastningen?

=YIELDDISC("1999-02-15"; "1999-03-01"; 99.795; 100; 2) returns 0.052823 or 5.2823 per cent.

## NOMAVKFÖRF

Beräknar den årliga avkastningen från en säkerhet, det vill säga räntan som betalas vid förfallodatumet.

#### Syntax

YIELDMAT(Settlement; Maturity; Issue; Rate; Price [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Emission är värdepapprets emissionsdatum.

Ränta är värdepapprets räntesats vid emission.

Pris är värdepapprets pris (inköpspriset) per 100 valutaenheter av nominellt värde.

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

Ett värdepapper köptes 1999-03-15. Det förfaller 1999-11-03. Emissionsdag var 1998-11-08. Räntesatsen är 6,25 %, priset är 100,0123 enheter. Basen är 0. Hur hög är avkastningen?

=YIELDMAT("1999-03-15"; "1999-11-03"; "1998-11-08"; 0.0625; 100.0123; 0) returns 0.060954 or 6.0954 per cent.

## NOMRÄNTA

Beräknar den årliga nominella räntesatsen, utifrån den effektiva räntan och antalet sammansatta perioder per år.

#### Syntax

NOMRÄNTA (EffektivRänta; P)

EffektivRänta är den effektiva räntan.

P är antalet periodiska ränteinbetalningar per år.

#### Example

Hur stora är de årliga nominalräntorna vid en effektiv ränta på 13,5% och tolv ränteinbetalningar per år?

=NOMRÄNTA(13,5 %;12) = 12,73%. Den nominella räntesatsen per år 12,73 %.

## NOMRÄNTA_ADD

Beräknar den årliga nominella räntan på basis av den effektiva räntan och antalet räntebetalningar per år.

De funktioner vars namn slutar med _ADD eller _EXCEL2003 returnerar samma resultat som motsvarande funktioner i Microsoft Excel 2003 utan suffixen. Funktioner utan suffix ger resultat som är baserade på internationell standard.

#### Syntax

NOMRÄNTA_ADD(EffektivRänta; P

EffektivRänta är den effektiva årliga räntesatsen.

P är antalet periodiska räntebetalningar per år.

#### Example

Vad uppgår den nominella räntan till vid 5,3543% effektiv ränta och betalning kvartalsvis?

=NOMRÄNTA_ADD(5,3543%;4) returnerar 0,0525 or 5,5 %.

## PDURATION

Beräknar antalet perioder som behövs för att en investering ska nå önskat värde.

#### Syntax

PDURATION(Rate; PV; FV)

Ränta är en konstant. Räntesatsen ska beräknas för hela löptiden. Räntesatsen per period räknas ut genom att dividera räntesatsen med den beräknade löptiden. Internräntan för en annuitet ska anges som Ränta/12.

Nuvärde är det nuvarande (aktuella) värdet. Kontantvärdet är insättningens storlek, eller det aktuella kontantvärdet för en naturaförmån. Ett positivt värde måste anges som insättningens värde, dvs. insättningen får inte vara 0 eller <0.

Slutvärde är det väntade värdet. Slutvärdet bestämmer insättningens önskade (framtida) värde.

#### Example

Vid en räntesats på 4,75%, ett nuvarande värde på 25 000 valutaenheter och ett framtida värde på 1 000 000 valutaenheter returneras en löptid på 79,49 betalningsperioder. Den periodiska betalningen räknas ut genom att det framtida värdet divideras med löptiden, alltså: 1 000 000/79,49=12 580,20.

## PRIS

Beräknar marknadsvärdet på en säkerhet med fast ränta och ett nominellt värde på 100 valutaenheter som en funktion av den uppskattade avkastningen.

#### Syntax

PRICE(Settlement; Maturity; Rate; Yield; Redemption; Frequency [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Ränta är den årliga nominella räntesatsen (kupongräntesatsen)

Avkastning är den årliga avkastningen för värdepappret.

Inlösen är det nominella inlösningsvärdet per 100 valutaenheter.

Frekvens är antalet räntebetalningar per år (1, 2 eller 4).

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

Ett värdepapper köptes 1999-02-15; förfallodatum är 2007-11-15. Den nominella räntesatsen är 5,75 %. Avkastningen är 6,5 %. Inlösningsvärdet är 100 valutaenheter. Räntan betalas halvårsvis (frekvensen är 2). Priset blir följande med beräkningsbas 0:

=PRICE("1999-02-15"; "2007-11-15"; 0.0575; 0.065; 100; 2; 0) returns 95.04287.

## PRISDISK

Beräknar priset per 100 valutaenheter i nominellt värde på en icke räntebärande säkerhet.

#### Syntax

PRICEDISC(Settlement; Maturity; Discount; Redemption [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Diskontering är diskonteringsräntan på ett värdepapper i procent.

Inlösen är det nominella inlösningsvärdet per 100 valutaenheter.

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

En säkerhet köptes 1999-02-15; förfallodatum är 1999-03-01. Diskontering i procent är 5,25 %. Värdet vid inlösen är 100. Vid beräkning på bas 2 blir prisreduktionen enligt följande:

=PRICEDISC("1999-02-15"; "1999-03-01"; 0.0525; 100; 2) returns 99.79583.

## PRISFÖRF

Beräknar priset per 100 valutaenheter i nominellt värde på en säkerhet, som betalar ränta på förfallodagen.

#### Syntax

PRICEMAT(Settlement; Maturity; Issue; Rate; Yield [; Basis])

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Emission är värdepapprets emissionsdatum.

Ränta är värdepapprets räntesats vid emission.

Avkastning är den årliga avkastningen för värdepappret.

Bas väljs i en lista med alternativ och indikerar hur året ska beräknas.

Bas | Beräkning
--- | ---
0 or missing | US-metod (NASD), 12 månader om 30 dagar
1 | exakt antal dagar per månad, exakt antal dagar per år
2 | exakt antal dagar per månad, år har 360 dagar
3 | exakt antal dagar per månad, år har 365 dagar
4 | Europa-metod, 12 månader om 30 dagar

#### Example

Betalning: 15 februari 1999, Förfallodag: 13 april 1999, Emission: 11 november 1998. Ränta: 6,1 procent, Avkastning: 6,1 procent, Bas: 30/360 = 0.

Priset beräknas på följande sätt:

=PRICEMAT("1999-02-15";"1999-04-13";"1998-11-11"; 0.061; 0.061;0) returns 99.98449888.

## SSVXEKV

Beräknar den årliga avkastningen på en statsobligation. En statsobligation köps på betalningsdatumet och säljs till det fullständiga värdet på förfallodagen, som måste infalla under samma år. En rabatt dras av från inköpspriset.

#### Syntax

SSVXEKV(Betalning; Förfallodag; Diskontering)

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Diskontering är den procentuella diskonteringen vid värdepapprets anskaffande.

#### Example

Betalning: 31 mars 1999, Förfallodag: 1 juni 1999, Diskonteringsränta: 9,14 procent.

Förräntningen för statsskuldsväxeln motsvarande ett värdepapper räknas ut på följande sätt:

=TBILLEQ("1999-03-31";"1999-06-01"; 0.0914) returns 0.094151 or 9.4151 per cent.

## SSVXPRIS

Beräknar priset på en statsobligation per 100 valutaenheter.

#### Syntax

SSVXPRIS(Betalning; Förfallodag; Diskontering)

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Diskontering är diskonteringsräntan i procent per anskaffningsdatum för värdepappret.

#### Example

Betalning: 31 mars 1999, Förfallodag: 1 juni 1999, Diskonteringsränta: 9 procent.

Priset på statsskuldsväxeln beräknas på följande sätt:

=TBILLPRICE("1999-03-31";"1999-06-01"; 0.09) returns 98.45.

## SSVXRÄNTA

Beräknar avkastningen av en statsobligation.

#### Syntax

SSVXRÄNTA(Betalning; Förfallodag; Pris)

Avräkning är värdepapprets inköpsdatum.

Förfallotid är det datum som värdepappret förfaller (upphör att gälla).

Pris är statsobligationens pris (inköpspriset) per 100 valutaenheter av nominellt värde.

#### Example

Betalning: 31 mars 1999, Förfallodag: 1 juni 1999, Pris: 98,45 valutaenheter.

Avkastningen på en statsskuldsväxel beräknas på följande sätt:

=TBILLYIELD("1999-03-31";"1999-06-01"; 98.45) returns 0.091417 or 9.1417 per cent.

Tillbaka till Finansfunktioner del ett

Till finansfunktionerna del 3

Functions by Category