Contenido
Índice 🔎︎

# Funciones de texto

Esta sección contiene descripciones de las funciones de Texto.

Para acceder a esta orden…

Insertar ▸ Función ▸ categoría Texto

## EXP.REG

Encuentra y extrae, u opcionalmente reemplaza, texto, con ayuda de expresiones regulares.

### WEBSERVICE

Obtiene contenido web a partir de un URI.

### FILTERXML

Aplica una expresión XPath en un documento XML.

### ENCODEURL

Devuelve una cadena codificada como URL.

## NUMERO.ARABE

Calcula el valor de un número romano. El intervalo de valores debe estar comprendido entre 0 y 3999.

#### Sintaxis

NUMERO.ARABE("Texto")

Texto es el texto que representa un número romano.

#### Ejemplo

=NUMERO.ARABE("MXIV") devuelve 1014.

=NUMERO.ARABE("MMII") devuelve 2002.

## LARGO

Calcula la longitud de una cadena, incluidos los espacios.

#### Sintaxis

LARGO("Texto")

Texto es el texto cuya longitud debe determinarse.

#### Ejemplo

=LARGO("Buenas tardes") devuelve 13.

=LARGO(12345.67) devuelve 8.

## CONCATENAR

Combina varias cadenas de caracteres en una sola.

#### Sintaxis

CONCATENATE(String 1 [; String 2 [; … [; String 255]]])

String 1[; String 2][; … ;[String 255]] are strings or references to cells containing strings.

#### Ejemplo

=CONCATENAR("Buenos ";"días, ";"Sra. ";"López") devuelve «Buenos días, Sra. López».

## IGUAL

Compara dos cadenas de texto y devuelve VERDADERO si son iguales. Esta función distingue entre mayúsculas y minúsculas.

#### Sintaxis

IGUAL("Texto1"; "Texto2")

Texto1 hace referencia al primer texto que se comparará.

Texto2 es el segundo texto que se va comparar.

#### Ejemplo

=IGUAL("microsystems";"Microsystems") devuelve FALSO.

## TEXTO

Converts a value into text according to a given format.

#### Sintaxis

TEXT(Value; Format)

Value is the value (numerical or textual) to be converted.

Formato es el texto que define el formato. Use separadores de decimales y millares de acuerdo con el idioma definido en el formato de celda.

#### Ejemplo

=TEXTO(12,34567;"###,##") devuelve el texto 12,35.

=TEXTO(12,34567;"000,00") devuelve el texto 012,35.

=TEXT("xyz";"=== @ ===") returns the text === xyz ===

Consulte también Códigos de formato numérico: códigos de formato personalizados definidos por el usuario.

## DECIMAL

Convierte texto con caracteres de un sistema numérico en un entero positivo en la base dada. La base debe estar entre 2 y 36. Los espacios y las tabulaciones se pasan por alto. El campo Texto no distingue mayúsculas y minúsculas.

Si la raíz es 16 se despreciarán los caracteres x, X, 0x o 0X que precedan al texto, así como los caracteres h o H agregados al final. Si la raíz es 2 se despreciarán los caracteres b o B agregados al final. Otros caracteres que no pertenezcan al sistema numérico provocarán un error.

#### Sintaxis

DECIMAL("Texto"; Base)

Texto es el texto que se debe convertir. Para diferenciar entre un número hexadecimal, por ejemplo A1 y la referencia a la celda A1, debe escribir el número entre comillas; por ejemplo, "A1" o "FACE".

Base indica la base del sistema numérico. Puede ser cualquier número entero positivo entre 2 y 36.

#### Ejemplo

=DECIMAL("17";10) devuelve 17.

=DECIMAL("FACE";16) devuelve 64206.

=DECIMAL("0101";2) devuelve 5.

## MINUSC

Convierte todas las letras mayúsculas de una cadena de texto en minúsculas.

#### Sintaxis

MINUSC("Texto")

Texto hace referencia al texto que se debe convertir.

#### Ejemplo

=MINUSC("Sun";2) devuelve sun.

## BASE

Convierte un entero positivo de una base especificada en texto del sistema numérico. Se utilizan los dígitos 0-9 y las letras A-Z.

#### Sintaxis

BASE(Number; Radix [; MinimumLength])

Número es el número entero positivo se debe convertir.

Radix indica la base del sistema numérico. Puede ser cualquier número entero positivo entre 2 y 36.

LongitudMínima (opcional) determina la longitud mínima de la secuencia de caracteres que se ha creado. Si el texto es más corto que la longitud mínima indicada, se agregan ceros a la izquierda de la cadena.

#### Ejemplo

=BASE(17;10;4) devuelve 0017 en el sistema decimal.

=BASE(17;2) devuelve 10001 en el sistema binario.

=BASE(255;16;4) devuelve 00FF en el sistema hexadecimal.

## UNICAR

Convierte un número de código en un carácter o letra Unicode.

#### Sintaxis

UNICAR(número)

#### Ejemplo

=UNICAR(169) da como resultado el carácter de derechos de autor, ©.

Consulte también la función UNICODE().

## ROMANO

Convierte un número en números romanos. El valor debe estar entre 0 y 3999, los modos pueden ser números enteros de 0 a 4.

#### Sintaxis

ROMAN(Number [; Mode])

Número es el número que se va a convertir a números romanos.

Modo (opcional) indica el grado de simplificación. Cuanto mayor sea el valor, mayor es la simplificación del número romano.

#### Ejemplo

=ROMANO(999) devuelve CMXCIX.

=ROMANO(999;0) devuelve CMXCIX.

=ROMANO(999;1) devuelve LMVLIV.

=ROMANO(999;2) devuelve XMIX.

=ROMANO(999;3) devuelve VMIV.

=ROMANO(999;4) devuelve IM.

## TEXTOBAHT

Convierte un número en texto tailandés, incluso los nombres de monedas tailandeses.

#### Sintaxis

TEXTOBAHT(Número)

Número es cualquier número. "Baht" se agrega a la parte entera del número y "Satang" se agrega a la parte decimal del número.

#### Ejemplo

=TEXTOBAHT(12,65) devuelve una cadena de caracteres tailandeses que representan «Doce bahts y sesentaicinco satangs».

## CARACTER

Convierte un número en un carácter según la tabla de códigos actual. El número puede ser un entero de dos o de tres dígitos.

Los códigos mayores que 127 pueden depender de la asignación de caracteres del sistema (por ejemplo, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) y, por ello, pueden no ser portátiles.

#### Sintaxis

CARACTER(Número)

Número es un número entre 1 y 255 que representa el valor de código del carácter.

#### Ejemplo

=CARACTER(100) devuelve el carácter «d».

="abc" & CARACTER(10) & "def" inserta un carácter de salto de renglón en la cadena.

## MONEDA

Convierte un número en una cantidad en el formato monetario, redondeada a la cantidad de decimales que especifique. En el campo Valor digite el número que quiere convertir en moneda. Opcionalmente, puede especificar el número de decimales en el campo Decimales. Si no se especifica ningún valor, todos los números en el formato monetario se mostrarán con dos decimales.

Debe establecer el formato de la divisa en la configuración del sistema.

#### Sintaxis

DOLLAR(Value [; Decimals])

Valor es un número, una referencia a una celda que contiene un número o una fórmula que da como resultado un número.

Decimales es el número opcional de posiciones decimales.

#### Ejemplo

=MONEDA(255) devuelve $255,00.

=MONEDA(367,456;2) devuelve $367,46. Utilice el separador decimal que se corresponda con la configuración regional actual.

## VALOR

Convierte una cadena de texto en un número.

#### Sintaxis

VALOR("Texto")

Texto es el texto que se debe convertir en un número.

#### Ejemplo

=VALOR("4321") devuelve 4321.

## UNICODE

Devuelve el código numérico del primer carácter Unicode de una cadena de texto.

#### Sintaxis

UNICODE("Texto")

#### Ejemplo

=UNICODE("©") devuelve el número Unicode 169 para el carácter de Copyright.

Consulte también la función UNICAR().

## IZQUIERDA

Devuelve el primer carácter o los primeros caracteres de un texto.

#### Sintaxis

LEFT("Text" [; Number])

Texto es el texto donde las palabras parciales iniciales deben determinarse.

Número (opcional) especifica el número de caracteres para el texto inicial. Si no se ha definido este parámetro, se devuelve un carácter.

#### Ejemplo

=IZQUIERDA("salida";3) devuelve “sal”.

## DERECHAB

Devuelve el último carácter o caracteres de un texto en DBCS (conjunto de caracteres de bytes dobles).

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

RIGHTB("Text" [; Number_bytes])

Texto es el texto cuya parte derecha se determinará.

Número_de_bytes (opcional) especifica la cantidad de caracteres que extraerá DERECHAB, medido en bytes.

#### Ejemplo

IZQUIERDAB("中国";1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, se devuelve un espacio en su lugar).

DERECHAB("中国";2) devuelve «国» (2 bytes constituyen un carácter DBCS completo).

DERECHAB("中国";3) devuelve « 国» (3 bytes constituyen un carácter DBCS y una mitad, se devuelve un espacio por la primera mitad).

DERECHAB("中国";4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).

DERECHAB("capuchino";5) devuelve «chino» (5 caracteres no DBCS, cada uno con la medida de 1 byte).

## DERECHA

Devuelve el último carácter o los últimos caracteres de un texto.

#### Sintaxis

RIGHT("Text" [; Number])

Texto es el texto para el que se va a determinar la parte derecha.

Número (opcional) es el número de caracteres desde la parte derecha del texto.

#### Ejemplo

=DERECHA("Sin";2) devuelve un.

## BUSCAR

Devuelve la posición de un segmento de texto dentro de una cadena de caracteres. Opcionalmente puede fijar el inicio de la búsqueda. El texto buscado puede ser un número o una cadena de caracteres. La búsqueda no distingue mayúsculas de minúsculas. Si no se encuentra el texto, se devuelve el error 519 (#VALOR).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

#### Sintaxis

SEARCH("FindText"; "Text" [; Position])

Encontrar_Texto es el texto que se debe buscar.

Texto es el texto donde se realiza la búsqueda.

Posición (opcional) es la posición en el texto donde se iniciará la búsqueda.

#### Ejemplo

=BUSCAR(54;998877665544) devuelve 10.

## ENCONTRAR

Devuelve la posición de una cadena de texto dentro de otra cadena. También puede definirse el punto de inicio de la búsqueda. El término buscado puede ser un número o una cadena de caracteres. La búsqueda distingue entre mayúsculas y minúsculas.

#### Sintaxis

FIND("FindText"; "Text" [; Position])

QuéEncontrar hace referencia al texto que se debe buscar.

Texto es el texto donde se realiza la búsqueda.

Posición (opcional) es la posición en el texto donde se iniciará la búsqueda.

#### Ejemplo

=BUSCAR(76;998877665544) devuelve 6.

## IZQUIERDAB

Devuelve los primeros caracteres de un texto en DBCS.

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

LEFTB("Text" [; Number_bytes])

Texto es la cadena de texto cuyas palabras parciales iniciales se determinarán.

Número_de_bytes (opcional) especifica la cantidad de caracteres que extraerá IZQUIERDAB, medido en bytes. Si no se define este parámetro, se devolverá un carácter.

#### Ejemplo

IZQUIERDAB("中国";1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, se devuelve un espacio en su lugar).

IZQUIERDAB("中国";2) devuelve «中» (2 bytes constituyen un carácter DBCS completo).

IZQUIERDAB("中国";3) devuelve «中 » (3 bytes constituyen un carácter DBCS y una mitad; por ello, el último carácter devuelto es un espacio).

IZQUIERDAB("中国";4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).

IZQUIERDAB("vacante";4) devuelve «vaca» (4 caracteres no DBCS, cada uno con la medida de 1 byte).

## CODIGO

Devuelve un código numérico para el primer carácter de una cadena de texto.

#### Sintaxis

CODIGO("Texto")

Texto es el texto para el que se buscará el código del primer carácter.

Los códigos mayores que 127 pueden depender de la asignación de caracteres del sistema (por ejemplo, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) y, por ello, pueden no ser portátiles.

#### Ejemplo

=CODIGO("Jerónimo") devuelve 74, =CODIGO("jeroglífico") devuelve 106.

El código utilizado en este caso no es el código ASCII, sino el código de la tabla de códigos actual.

## FIJO

Devuelve un número como texto con un número especificado de decimales y separadores de miles opcionales.

#### Sintaxis

FIXED(Number; Decimals [; NoThousandsSeparators])

Número hace referencia al número al que se va a dar formato.

Decimales hace referencia al número de posiciones decimales que se mostrarán.

No_separar_millares (opcional) determina si se utiliza el separador de millares. Si el parámetro es un número no igual a 0, se elimina el separador de millares. Si el parámetro es igual a 0 o si no aparece en absoluto, se muestran los separadores de millares de la configuración regional actual.

#### Ejemplo

=FIJO(1234567,89;3) devuelve 1.234.567,890 como cadena de texto.

=FIJO(1234567,89;3) devuelve 1234567,890 como una cadena de texto.

## EXTRAE

Devuelve una cadena de texto de un texto. Los parámetros especifican la posición inicial y el número de caracteres.

#### Sintaxis

EXTRAE("Texto"; Comienzo; Número)

Texto es el texto que contiene los caracteres que se van a extraer.

Inicio es la posición del primer carácter del texto que se va a extraer.

Número especifica el número de caracteres en la parte del texto.

#### Ejemplo

=EXTRAE("oficina";2;2) devuelve «fi».

## EXTRAEB

Devuelve una cadena de texto en DBCS. Los parámetros especifican la posición inicial y la cantidad de caracteres.

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

EXTRAEB("Texto"; Comienzo; Número_de_bytes)

Texto es el texto que contiene los caracteres que se van a extraer.

Inicio es la posición del primer carácter del texto que se extraerá.

Número_de_bytes especifica la cantidad de caracteres que EXTRAEB extraerá del texto, en bytes.

#### Ejemplo

EXTRAEB("中国";1;0) devuelve «» (0 bytes es siempre una cadena vacía).

EXTRAEB("中国";1;1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, se devuelve un espacio en su lugar).

EXTRAEB("中国";1;2) devuelve «中» (2 bytes constituyen un carácter DBCS completo).

EXTRAEB("中国";1;3) devuelve «中 » (3 bytes constituyen un carácter DBCS y una mitad; por ello, el último carácter devuelto es un espacio).

EXTRAEB("中国";1;4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).

EXTRAEB("中国";2;1) devuelve « » (el byte en la posición 2 no está en el comienzo de un carácter en una cadena DBCS; por lo tanto, se devuelve un espacio en su lugar).

EXTRAEB("中国";2;2) devuelve « » (el byte en la posición 2 es la última mitad del primer carácter en una cadena DBCS; los dos bytes solicitados constituyen la última mitad del primer carácter y la primera mitad del segundo; por lo tanto, se devuelven dos espacios).

EXTRAEB("中国";2;3) devuelve « 国» (el byte en la posición 2 no está en el comienzo de un carácter en una cadena DBCS, se devuelve un espacio por la posición 2).

EXTRAEB("中国";3;1) devuelve « » (el byte en la posición 3 está en el comienzo de un carácter en una cadena DBCS, pero 1 byte es solo la mitad de un carácter DBCS y, por lo tanto, se devuelve un espacio en su lugar).

EXTRAEB("中国";3;2) devuelve «国» (el byte en la posición 3 está en el comienzo de un carácter en una cadena DBCS, y 2 bytes constituyen un carácter DBCS).

EXTRAEB("oficina";2;3) devuelve «fic» (el byte en la posición 2 se encuentra en el comienzo de un carácter en una cadena no DBCS, y 3 bytes constituyen 3 caracteres en estas cadenas).

## LIMPIAR

Elimina de la cadena todos los caracteres que no se pueden imprimir.

#### Sintaxis

LIMPIAR("Texto")

Texto hace referencia al texto del que se eliminarán todos los caracteres no imprimibles.

## ESPACIOS

Elimina los espacios de una cadena de caracteres y deja un solo espacio entre palabras.

#### Sintaxis

ESPACIOS("Texto")

Text se refiere al texto cuyos espacios se han de eliminar.

#### Ejemplo

=ESPACIOS(" hola, mundo ") devuelve «hola, mundo» sin los espacios inicial y final y con un único espacio entre las palabras.

## NOMPROPIO

En el caso de una cadena de texto, convierte en mayúscula la inicial de todas las palabras de la cadena.

#### Sintaxis

NOMPROPIO("Texto")

Texto hace referencia al texto que se debe convertir.

#### Ejemplo

=PROPER("the document foundation") returns The Document Foundation.

## T

Esta función devuelve el texto de destino, o una cadena de texto vacía si el destino no es texto.

#### Sintaxis

T(Valor)

Si Valuor es una cadena de texto o se refiere a una cadena de texto. T devolverá esa cadena; de lo contrario devolvera una cadena en vacia.

#### Ejemplo

=T(12345) devuelve una cadena vacía.

=T("12345") devuelve la cadena 12345.

## ASC

La función ASC convierte caracteres ASCII y katakana a la mitad de la anchura normal. Devuelve una cadena de texto.

Vea https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions para una tabla de conversión.

#### Sintaxis

ASC("Texto")

Texto es el texto que contiene los caracteres que se van a convertir.

Consulte también la función JIS.

## JIS

La función JIS convierte caracteres ASCII y katakana de anchura media a anchura completa. Devuelve una cadena de texto.

Vea https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions para una tabla de conversión.

#### Sintaxis

JIS("Texto")

Texto es el texto que contiene los caracteres que se van a convertir.

Consulte también la función ASC.

## LARGOB

Para los idiomas que utilizan un conjunto de caracteres de bytes dobles (DBCS), devuelve la cantidad de bytes usada para representar los caracteres de una cadena de texto.

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

LARGOB("Texto")

Texto es el texto cuya longitud debe determinarse.

#### Ejemplo

LARGOB("中") devuelve 2 (1 carácter DBCS, equivalente a 2 bytes).

LARGOB("中国") devuelve 4 (2 caracteres DBCS, cada uno equivalente a 2 bytes).

LARGOB("Caifanes") devuelve 8 (8 caracteres no DBCS, cada uno con la medida de 1 byte).

=LARGOB("Buenas tardes") devuelve 13.

=LARGOB(12345.67) devuelve 8.

## MAYUSC

Pasa la cadena especificada en el campo de texto a mayúsculas.

#### Sintaxis

MAYUSC("Texto")

Texto hace referencia a las letras en minúsculas que desea convertir a mayúsculas.

#### Ejemplo

=MAYUSC("Buenos días") devuelve BUENOS DÍAS.

## SUSTITUIR

Reemplaza un fragmento de texto por otro nuevo dentro de una cadena de caracteres.

#### Sintaxis

SUBSTITUTE("Text"; "SearchText"; "NewText" [; Occurrence])

Texto es el texto en el que se van a intercambiar los segmentos de texto.

Buscar_texto es el segmento de texto que se va a sustituir (un número de veces).

texto_nuevo es el texto que va a sustituir al segmento de texto.

Aparición (opcional) indica la aparición del texto buscado que se reemplazará. Si no se especifica este parámetro, el texto de la búsqueda se reemplazará en todas partes.

#### Ejemplo

=SUSTITUIR("123123123";"3";"abc") devuelve 12abc12abc12abc.

=SUSTITUIR("123123123";"3";"abc";2) devuelve 12312abc123.

## REPETIR

Repite una cadena de caracteres el número de veces especificado.

#### Sintaxis

REPETIR("Texto"; Número)

Texto es el texto que se debe repetir.

Número es el número de repeticiones.

El resultado puede tener como máximo 255 caracteres.

#### Ejemplo

=REPETIR("Buenos días") devuelve Buenos díasBuenos días.

## REEMPLAZAR

Sustituye parte de una cadena de texto con una cadena de texto distinta. Esta función se puede utilizar para sustituir caracteres y números (que se convierten automáticamente en texto). El resultado de la función siempre es un texto. Para proseguir con la operación de cálculo con un número reemplazado por texto, es preciso transformar el resultado de nuevo en número; para ello, se utiliza la función VALOR.

Si no desea que un texto que contenga números se interprete como número y se convierta en texto automáticamente deberá escribirlo entre comillas.

#### Sintaxis

REEMPLAZAR("Texto"; Posición; Longitud; "texto_nuevo")

Texto hace referencia al texto del que se sustituirá una parte.

Posición hace referencia a la posición del texto en la que comenzará la sustitución.

Longitud es el número de caracteres en Texto que se va a sustituir.

texto_nuevo hace referencia al texto que sustituye a Texto.

#### Ejemplo

=REEMPLAZAR("1234567";1;1;"444") devuelve "444234567". Un carácter en la posición 1 se sustituye por el texto_nuevo completo.

Temas relacionados

Funciones por categoría