# Maintainer (Arch): Felix Yan <felixonmars@gmail.com>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): dorphell <dorphell@archlinux.org>
# Maintainer: Márcio Silva <coadde@hyperbola.info>
# Contributor: Tobias Dausend <throgh@hyperbola.info>

pkgname=enchant
pkgver=1.6.0
_debver=$pkgver
_debrel=11.1
pkgrel=5
pkgdesc="A wrapper library for generic spell checking"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('aspell' 'glib2' 'hspell' 'hunspell' 'ispell' 'libvoikko')
makedepends=('quilt')
source=("https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.sig}
        "https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz"{,.sig})
sha512sums=('63850cee245d3600ee08480bd67f37e9665c374031a2356a4624d245f29daede4005f0380f85e6c9fee0766ee2bbc43b6476dcc6a90067aee46656b006721a7e'
            'SKIP'
            '90b36e5bc51449600e1074c6dc36e725776d291aab98a2c681baae145c6081a8f722ec749f9960577b634917dc8add239258739817d71c548534d908fbd3ccda'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}


build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING.LIB -t $pkgdir/usr/share/licenses/$pkgname
}
